「１．アップロード画面の作成」で、画像と題名、本文を登録（サーバーに送信）するところまでを示したが、本稿では、サーバーに保存されたデータをロードして表示させるためのステップのお勉強である。

　表示としては、displayDoc.swfで最新データ（ここでは6件）を表示させるswfを作成し、そのswfをスクロールペインを用いた finaldisplay.swf で最終的にサイト画面に表示させる仕組みになっている。

本ページはサイト（更新）画面の作成で、アップロード画面の作成は　<< こちらに <<　あります。　（別ウインドウで開きます）

displayDoc.fla
　特になし

finaldisplay.fla
　コンポーネントウインドウからのライブラリーにScrollPaneをドラッグしておく。

スクリプト（as2.0,　_root、FRAME1に記述）

displayDoc.fla

System.useCodepage = true;

//ドキュメント（ログファイル　doc.log）のロード
var myVars:LoadVars = new LoadVars();
myVars.onData = function(myStr:String):Void {
  if (myStr != undefined) {
    displayDoc(myStr);
  } else {
    trace("Unable to load text file.");
  }
};
myVars.load("doc.log");

//ドキュメント表示関数
function displayDoc(myStr) {
  var txtData:Array = myStr.split("\n");
  var dataTotal = txtData.length-1;
  if (dataTotal) {
    for (j=0; j<dataTotal; j++) {
      createTF(j);
      var itemData:Array = txtData[j].split("|");
      image = "simages/s"+itemData[0];
      imageL = 'images/L'+itemData[0];
      title = itemData[1];
      contents = "\n\n"+itemData[2];
      doc = "<B>"+title+"</B>";
      doc += "<a href='"+imageL+"' target='_blank'><img src='"+image+"' align='left'></a>";
      doc += contents;
      this["textBox"+j].htmlText = doc;
    }
  }
}

//ドキュメント表示用テキストフィールド作成関数
function createTF(n) {
  textBox = this.createTextField("textBox"+n,n,5,5+150*n,600,150);
  with (textBox) {
    border = true;
    borderColor = 0x999999;
    html = true;
    wordWrap = true;
  }
}

finaldisplay.fla

//スクロールペインのインスタンス化
docPane = this.createClassObject(mx.containers.ScrollPane, "docPane", 100);
docPane.setSize(630,465);
docPane._x = 0;
docPane._y = 0;
docPane.vScrollPolicy = "on";
//スクロールペインに表示swfの読み込み
docPane.contentPath = "displayDoc.swf";